// Задача "Луна"
// XVIII командный чемпионат школьников Санкт-Петербурга по программированию
// Автор задачи: Юрий Петров
// Автор чекера: Владимир Ульянцев, ulyantsev@rain.ifmo.ru

uses
    testlib, Math, SysUtils;
const
    MAXH = 50;
    MAXW = 50;
type
    int = longint;
var
    w, h, i, j : int;
    a : array [1..MAXH, 1..MAXW] of boolean;
    s : string;
    jury_r, r, x, y : int;

begin
    w := inf.readlongint;
    h := inf.readlongint;
    s := inf.readstring;

    for i := 1 to h do begin
        s := inf.readstring;
        for j := 1 to w do begin
            a[i][j] := (s[j] = '*');
        end;
    end;

    jury_r := ans.readlongint;
    r := ouf.readlongint;
    
    if (r < jury_r) then begin
        quit(_wa, 'Jury has better solution');
    end;

    y := ouf.readlongint;
    x := ouf.readlongint;

    if ((x + r > h) or (x - r < 1) or (y + r > w) or (y - r < 1)) then begin
        quit(_wa, 'Moon with radius ' + IntToStr(r) + ' can''t be placed at (' 
                  + IntToStr(x) + ', ' +  IntToStr(y) + ')');
    end;

    for i := x - r to x + r do begin
        for j := y - r to y + r do begin
            if (sqr(x - i) + sqr(y - j) <= sqr(r)) then begin
                if (not a[i][j]) then begin
                    quit(_wa, 'In position (' + IntToStr(i) + ', ' 
                              +  IntToStr(j) + ') moon is not white');
                end;
            end;
        end;
    end;

    if (r > jury_r) then begin
        quit(_fail, 'Contestant has better solution');
    end;

    quit(_ok, 'OK, moon found');
end.
