{$H+}
uses
  testlib, SysUtils;

var
	source, target, sumStr: string;
	sourceLen, targetLen, left, right, right2, i, j, sum: longint;

begin 
	source := inf.readstring;
	sourceLen := length(source);
	target := inf.readstring;
	targetLen := length(target);
	left := ouf.readlongint;
	right := ouf.readlongint;
	right2 := right - (sourceLen - targetLen);

	if (left <= 0) then begin
		quit(_wa, 'Позиция левой цифры меньше ноля, а именно ' + intToStr(left));		
	end;
	
	if (right > sourceLen) then begin
		quit(_wa, 'Позиция правой цифры (' + intToStr(right) + 
			') больше длины строки (' + intToStr(sourceLen) + ')');		
	end;
	
	if (right < left) then begin
		quit(_wa, 'Позиция правой цифры меньше чем левой (' + intToStr(right) + ' < ' + intToStr(left) + ')');
	end;
	
	if (right2 < left) then begin
		quit(_wa, 'Цифр, не замененых на сумму, слишком много');
	end;

	for i := 1 to left - 1 do begin
		if (source[i] <> target[i]) then begin
			quit(_wa, 'Символ результата номер ' + intToStr(i) + ' не совпадает с искомым: ' + source[i] + ' <> ' + target[i] + ', эта позиции находится до тех цифр которые заменили на сумму');
		end;
	end;
	for i := right + 1 to sourceLen do begin
		j := targetLen - (sourceLen - i);
		if (source[i] <> target[j]) then begin
			quit(_wa, 'Символ результата номер ' + intToStr(j) + ' не совпадает с искомым: ' + source[i] + ' <> ' + target[j] + ', эта позиции находится после тех цифр которые заменили на сумму');		
		end;
	end;
	sum := 0;
	for i := left to right do begin
		sum := sum + ord(source[i]) - ord('0');
	end;
	sumStr := intToStr(sum);

	if right2 - left + 1 <> length(sumStr) then begin
		quit(_wa, 'После замены получилось число другой длины');
	end;
	for i := 1 to length(sumStr) do begin
		if (target[left + i - 1] <> sumStr[i]) then begin
			quit(_wa, 'Символ результата номер ' + intToStr(left + i - 1) + ' не совпадает с искомым: ' + target[left + i - 1] + ' <> ' + sumStr[i] + ', и это одна из цифр которая получилась как сумма.');	
		end;		
	end;
	quit(_ok, 'ОК, из ' + intToStr(sourceLen) + ' цифр получились ' + intToStr(targetLen));
end.
