program travel;
{ vim: set nospell:
}

const
  maxr = 500;
  maxn = 1000;
  dh: array[1..4] of longint = (1, 0, -1, 0);
  dw: array[1..4] of longint = (0, 1, 0, -1);
  ds: string = 'SENW';

function min( a, b: longint ): longint;
begin
  if a < b then
    min := a
  else
    min := b;
end;

var
  w, h, n, ans: longint;
  i, j, k, t, rr: longint;
  map: array[1..maxr, 1..maxr] of char;
  vh, vw, ql, qr, uh, uw, th, tw: longint;
  d, r, b: array[1..maxr, 1..maxr] of longint;
  qh, qw: array[-maxr*maxr..maxr*maxr] of longint;
  path: array[1..maxr + maxr + 2 * maxn] of longint;
  cr, cf: char;

begin
  assign(input, 'travel.in');
  reset(input);
  assign(output, 'travel.out');
  rewrite(output);

  read(w, h, n);
  vh := -1;
  vw := -1;
  for i := 1 to h do
    for j := 1 to w do begin
      repeat
        read(map[i, j]);
      until map[i, j] in ['A', 'T', 'V'];
      if map[i, j] = 'V' then begin
        vh := i;
        vw := j;
      end;
    end;

  fillchar(d, sizeof(d), $7f);
  ql := 0;
  qr := 0;
  r[vh, vw] := -1;
  d[vh, vw] := 0;
  inc(qr);
  qh[qr] := vh;
  qw[qr] := vw;
  while ql < qr do begin
    inc(ql);
    uh := qh[ql];
    uw := qw[ql];
    for i := 1 to 4 do begin
      th := uh + dh[i];
      tw := uw + dw[i];
      if (th < 1) or (th > h) or (tw < 1) or (tw > w) then
        continue;
      if d[th, tw] <> $7f7f7f7f then
        continue;
      r[th, tw] := i;
      if map[th, tw] = 'T' then begin
        d[th, tw] := d[uh, uw];
        qh[ql] := th;
        qw[ql] := tw;
        dec(ql);
      end else begin
        d[th, tw] := d[uh, uw] + 1;
        inc(qr);
        qh[qr] := th;
        qw[qr] := tw;
      end;
    end;
  end;

  for i := 1 to h do
    for j := 1 to w do begin
      b[i, j] := 0;
      if map[i,j] <> 'T' then
        continue;
      inc(b[i, j]);
      for t := 1 to 4 do begin
        th := i + dh[t];
        tw := j + dw[t];
        if (th < 1) or (th > h) or (tw < 1) or (tw > w) then
          continue;
        if map[th, tw] = 'T' then
          inc(b[i, j]);
      end;
    end;

  ans := longint(1e9);
  for i := 1 to h do
    for j := 1 to w do begin
      if b[i, j] = 0 then
        continue;
      if b[i, j] = 1 then
        ans := min(ans, abs(i - vh) + abs(j - vw) + 2 * (n - 1))
      else
        ans := min(ans, d[i, j] + n);
    end;
  for i := 1 to h do
    for j := 1 to w do begin
      if b[i, j] = 0 then
        continue;
      if (b[i, j] = 1) and (ans = abs(i - vh) + abs(j - vw) + 2 * (n - 1)) then begin
        cr := '?';
        cf := '?';
        while vh < i do begin
          cf := 'S';
          cr := 'N';
          write(cf);
          inc(vh);
        end;
        while vh > i do begin
          cf := 'N';
          cr := 'S';
          write(cf);
          dec(vh);
        end;
        while vw < j do begin
          cf := 'E';
          cr := 'W';
          write(cf);
          inc(vw);
        end;
        while vw > j do begin
          cf := 'W';
          cr := 'E';
          write(cf);
          dec(vw);
        end;
        for t := 2 to n do begin
          write(cr);
          write(cf);
        end;
        writeln;
        halt;
      end;
      if (b[i, j] > 1) and (ans = d[i, j] + n) then begin
        k := 0;
        th := i;
        tw := j;
        while r[th, tw] <> -1 do begin
          rr := r[th, tw];
          inc(k);
          path[k] := rr;
          th := th - dh[rr];
          tw := tw - dw[rr];
        end;
        for t := k downto 1 do begin
          if n <= 0 then
            continue;
          write(ds[path[t]]);
          vh := vh + dh[path[t]];
          vw := vw + dw[path[t]];
          if map[vh, vw] = 'T' then
            dec(n);
        end;
        while n > 0 do begin
          for t := 1 to 4 do begin
            th := vh + dh[t];
            tw := vw + dw[t];
            if (th < 1) or (th > h) or (tw < 1) or (tw > w) then
              continue;
            if map[th, tw] = 'T' then begin
              write(ds[t]);
              vh := th;
              vw := tw;
              dec(n);
              break;
            end;
          end;
        end;
        writeln;
        halt;
      end;
    end;

  halt(1);
end.

